Les oeuvres d’art dans DBpedia

Dans le cadre du projet Data&Musée, nous sommes amenés à nous intéresser aux données liées disponibles au sujet des œuvres d’art, aux artistes et aux musées et monuments qui ont un lien avec ces œuvres.

Nombre d’œuvres et leurs types

Nous avons cherché dans DBpedia les entités des types CreativeWork, Painting et Artwork.

select ?type (count(distinct ?oeuvre) as ?c)
where {
VALUES ?type {<http://schema.org/CreativeWork> 
              <http://schema.org/Painting> 
              <http://dbpedia.org/ontology/Artwork> 
              <http://dbpedia.org/ontology/Painting> }
?oeuvre a ?type .
}
group by ?type
order by desc(?c)

ce qui donne

Liens entre des œuvres et des musées

Maintenant, cherchons celles qui ont un lien direct avec un musée:

select ?type (count(distinct ?oeuvre) as ?c)
where {
VALUES ?type {<http://schema.org/CreativeWork> 
              <http://schema.org/Painting> 
              <http://dbpedia.org/ontology/Artwork> 
              <http://dbpedia.org/ontology/Painting> }
?oeuvre a ?type .
{ ?oeuvre ?link ?museum } UNION {?museum ?link ?oeuvre}.
?museum a dbo:Museum
}group by ?type
order by desc(?c)

donne

On peut se poser la question du nombre d’entités de type dbo:Museum:

select (count(distinct ?museum) as ?c)
where {
?museum a dbo:Museum
}

On en trouve 10153. Ce qui suggère que de nombreux musées sont connus, mais peu directement reliés à des œuvres.

Liens entre des oeuvres et des personnes

Voyons maintenant à quel point les oeuvres sont reliées à des artistes:

select ?type (count(?oeuvre) as ?c)
where {
VALUES ?type {<http://schema.org/CreativeWork> 
              <http://dbpedia.org/ontology/Artwork> 
               }
?oeuvre a ?type .
?oeuvre ?link ?person .
?person a dbo:Artist
}group by ?type
order by desc(?c)

donne

On voit que, dans DBpedia,  les œuvres sont fortement liées à des artistes.

En cherchant par quels liens:

select distinct ?link
where {
VALUES ?type {<http://schema.org/CreativeWork> 
              <http://dbpedia.org/ontology/Artwork> 
               }
?oeuvre a ?type .
?oeuvre ?link ?person .
?person a dbo:Artist
}

on voit que de nombreux liens suggèrent qu’il s’agit d’œuvres musicales, littéraires ou cinématographiques, qui sont relativement hors du champ de Data&Musée.

Cela ouvre la question de savoir si DBpedia couvre bien la peinture et la sculpture. Nous laisserons cette question pour un autre billet.